Jenkins for the noobs

.
├── resources # Static files that can be used in vars scripts
├── src       # Groovy source files
│   └── common
│       └── Semver.groovy
└── vars      # Groovy scripts that can be used in Jenkinsfiles
    └── myFunction.groovy

class SharedLibLoader {
  public static final String RESOURCES_FOLDER = '.git/shared-lib-scripts'
  private static final String RESOURCES_INDEX_FILE_PATH = 'index.json'
  

  /** We use base 64 for all files since some are binary files and get screwed with other encodings */
  private static final String SAFE_ENCODING = 'Base64'
  /**
   * Retrieves the shared library resources index and from there, gets all the files from the
   * common and requested folders and writes them in (git-ignored) folder
   * {@link Utilities#RESOURCES_FOLDER} with pipeline step writeFile
   * (which can only copy inside the workspace).
   */
  
  static void initializeSharedLibrary (final def mainScript, final String jobFolder, final String... otherFolders) {
    mainScript.echo 'Initializing shared library'

    final String indexAsString = mainScript.libraryResource(RESOURCES_INDEX_FILE_PATH)
    final String indexPath = "${RESOURCES_FOLDER}/${RESOURCES_INDEX_FILE_PATH}"
    mainScript.writeFile file: indexPath, text: indexAsString
    final List resources = (List) mainScript.readJSON(file: indexPath)

    final Set folders = new HashSet<>()
    folders.add('common')
    folders.add(jobFolder)
    otherFolders.each { folders.add(it) }
    writeAllResourcesInTemporaryFolder(mainScript, resources, folders)
  }
  

  private static Object writeAllResourcesInTemporaryFolder (final def mainScript, final List resources, final Set jobFolders) {
    resources
      .findAll { final String resource ->
        jobFolders.any { resource.startsWith("${it}/") }
      }
      .each { final String resource ->
        mainScript.echo "Retrieving resource file ${resource}"
        final String resourceContent = mainScript.libraryResource resource: resource, encoding: SAFE_ENCODING
        mainScript.writeFile(
          file: "${RESOURCES_FOLDER}/${resource}",
          text: resourceContent,
          encoding: SAFE_ENCODING
        )
      }
  }
  
}